% Metapost-File E28 Frontansicht
% Nico Hoffmann, 06/2005, 07/2005, 12/2005
%
% copyright: GNU, siehe http://de.wikipedia.org/wiki/GNU_Free_Document_License
%
% Metapost-Aufruf: mpost e28.mp -tex=latex


verbatimtex
\documentclass[10pt]{article}
\usepackage[T1]{fontenc}
\usepackage[latin1]{inputenc}
\usepackage{graphicx}
%\usepackage{geometry}
\begin{document}

\thispagestyle{empty}
\sffamily
\bfseries

etex
input graph

beginfig(1);

  %Skalierung
  numeric u, k;
  u := 1mm; % x-Koordinate
  k := 1mm; % y-Koordinate

  % Farben fuer das Logo:
  color lack, unten, orange, light, chrome, dunkel, lackdunkel, polster;
  lack := red;   % Wagenfarbe
  unten := white; % Hintergrund
  orange := red + 0.3*blue + 0.6*green; % fuer den Blinker
  light := 0.8*white;     % Scheinwerfer
  chrome := light;        % Chromteile
  dunkel := 0.2*white;      % z.B. Emblem
  lackdunkel := 0.4*lack; % Sicken
  polster := 0.8*blue +0.6*red +0.6*green;   % Polster
  
  def eine_seite(expr u, k) =
% Vorderansicht
    path vertnull, reifen, frontu, frontub, nsw, blinker, sstange, numsch, grill;
    path blmotor, niere, sickea, sickeb, sickec, holma, dach, aspiegel;
    path frontscheibe, rspiegel, kopfst, sitz;
%    vertnull := (0u, 13k)--(0u,87k); % Vertikale Grundlinie Fahrzeugmitte
    reifen := (37u,1k)..(37.3u,0.3k)..(38u,0k)--(49u,0k)..(49.7u,0.3k)..(50u,1k)--(50u,26k)--(37u,26k)--cycle; % Reifen
    frontu := (0u,13k)--(40u,13k)..(47u,20k)..(49u,26k)--(0u,26k)--cycle; 
    frontub := (0u,20k)--(47u,20k); % Linie unterhalb Blinker/NSW
    nsw := (24u,21k)--(34u,21k)--(34u,25k)--(24u,25k)--cycle; % der NSW
    blinker := (35u,21k)--(46.5u,21k)..(47.8u,24k)..(48u,25k)--(35u,25k)--cycle; % der Blinker
    sstange := (0u,30k)--(50u,30k)..(50.5u,29.8k)..(51u,29k)--(51u,27k)..(50.5u,26.2k)..(50u,26k)--(17u,26k)--(17u,28k)--(0u,28k)--cycle; % die Stossstange
    numsch := (0u,28k)--(17u,28k)--(17u,22k)--(0u,22k)--cycle; % Num.-Schild
    grill := (0u,44.5k)--(8u,44.5k)--(9u,44k)--(43u,43k)..(45u,40k)..(46u,34k)..(45u,31k)--(0u,31k)--cycle; % der Kuehlergrill
    blmotor := (0u,30k)--(51u,30k)..(51.7u,31k)..(52u,32k)--(52u,43k)--(51u,46k)..(49u,50k)..(46u,54k)--(45u,56k)..(20u,57k)..(0u,58k)--cycle; % Motorhaube, Kotfluegel
    niere := (3u,31k)--(6u,31k)..(7u,31.5k)..(7.5u,33k)--(8u,42.5k)..(7.7u,43k)..(7u,43.5k)--(2u,43.5k)..(1.5u,43k)..(1u,41.5k)--(1u,32.5k)..(1.5u,31.5k)..(2u,31k)--cycle; % die Niere
    sickea := (9u,45k)..(11.5u,50k)..(17u,55k); % auf der Motorhaube
    sickeb := (43u,44k)--(45u,53k); % Spalt zw. Haube und Kotfluegel
    sickec := (45u,43k)..(46u,43.5k)..(50u,46k);
    holma := (44u,55k)..(41u,70k)..(35u,83k);
    dach := (35u,83k)..(20u,84.5k)..(0u,85k);
    aspiegel := (45u,56k)--(55u,58k)..(55.5u,58.5k)..(56u,60k)--(56u,64k)..(55.5u,65.5k)..(54u,66k)--(47u,66k)..(46u,65.5k)..(44u,64k)--cycle;
    frontscheibe := (0u,57k)--(44u,55k)--(44u,56k)..(41u,70k)..(35u,83k)--(35u,83k)..(20u,84.5k)..(0u,85k)--cycle;
    rspiegel := (0u,83.5k)--(1u,83.5k)--(1u,80k)--(6u,80k)..(8u,78k)..(6u,76k)--(0u,76k)--cycle;
    kopfst := (14u,63k)--(14u,71k)..(14.5u,71.7k)..(15u,72k)--(29u,72k)..(29.5u,71.7k)..(30u,71k)--(30u,63k)..(29.5u,62.3k)..(29u,62k)--(15u,62k)..(14.5u,62.3k)..cycle;

    % Sitze
    pair si[];
    si11 := (0u,57k); si12 := (44u,55k); % Unterkante Frontscheibe
    si3 = (10u,50k); si4 = (34u,50k);
    si5 = (11u,61k); si6 = (33u,61k);
    si7 = (10u,60k); si8 = (34u,60k);
    si9= whatever[si7,si3] = whatever [si11,si12];
    si10 = whatever[si4,si8] = whatever[si11,si12];
    
%    draw vertnull;
    fill reifen withcolor dunkel;
    fill frontu withcolor lack;
    draw frontub withpen pencircle scaled 0.5u withcolor dunkel;
    fill nsw withcolor light;
    fill blinker withcolor orange;
    fill sstange withcolor dunkel;
    fill numsch withcolor dunkel;
    fill blmotor withcolor lack;
    fill grill withcolor dunkel;
    fill fullcircle xscaled 10u yscaled 10k shifted (38u,38k) withcolor light; % Hauptscheinwerfer
    fill fullcircle xscaled 8.5u yscaled 8.5k shifted (27u,38k) withcolor light; % Fernscheinwerfer
    draw niere withpen pencircle scaled 1u withcolor white;
    draw sickea withpen pencircle scaled 1u withcolor lackdunkel;
    draw sickeb withpen pencircle scaled 1u withcolor lackdunkel;
    draw sickec withpen pencircle scaled 1u withcolor lackdunkel;
    fill frontscheibe withcolor light;
    draw holma withpen pencircle scaled 3u withcolor lack;
    fill aspiegel withcolor dunkel;
    draw dach withpen pencircle scaled 3u withcolor lack;
    fill rspiegel withcolor dunkel;
    fill si9--si7..si5--si6..si8--si10--cycle withcolor polster; % Sitze
    fill kopfst withcolor polster;
    fill halfcircle--cycle rotated 270 xscaled 5u yscaled 1.5k shifted (0u,47k) withcolor dunkel; % Emblem
  enddef;

  fill unitsquare xscaled 80u yscaled 140u shifted (0u,-30k) withcolor unten;
  fill unitsquare xscaled -80u yscaled 140u shifted (0u,-30k) withcolor unten;

  eine_seite(u,k);   % linke Seite

  % Kombiinstrument / Lenkrad
  pair m[]; m1=(7u,50k); m2=(17u,59k); m3=(19u,60k); m4=(26u,60k);
  m5=(28u,59k); m6=(38u,50k);
  m11=(0u,57k); m12=(44u,55k); % unterkante Frontscheibe
  m7 = (m1--m2) intersectionpoint (m11--m12);
  m8 = (m5--m6) intersectionpoint (m11--m12);

  fill m7--m2..m3--m4..m5--m8--cycle withcolor dunkel;

  eine_seite(-u,k);  % rechte Seite

  % Grundlinie
%  draw (-60u,0k)--(60u,0k) withpen pencircle scaled 1k withcolor dunkel;

  label.bot(btex E28 Forum etex, (0u,0k)) scaled 7 withcolor dunkel;

endfig;

end